One of the most important features of the SAP HR recruitment module is the automatic applicant correspondence functionality. You can create correspondence with SAPscript or with Microsoft Word. In both cases, the system provides standard text variables to be included in letters.

However, most companies working with recruitment in R/3 need special fields that are not available in standard SAP. The system allows you to create your own text variables. You need only basic ABAP skills and an understanding of data structures in HR. The technique is similar for MS Word and for SAPscript. My example focuses on MS Word and mentions the major differences when you use SAPscript.

I’ll describe step by step how to implement the custom text variable to add the author’s initials to a letter. The screenshots are taken from R/3 4.7 with Extension Set 1.10, but the instructions work without big differences with other releases. The ABAP coding is straightforward without following the syntax of ABAP Objects so that everyone with basic ABAP skills will understand it. You can use the same technique to meet your organization’s specific business needs. (See the sidebar, “Other Text Variables You Can Use.”)

This article refers only to the Recruitment module in R/3; it doesn’t apply to the SAP E-Recruiting solution, which is a different product.

Adding a Text Variable

In many cases, customers want to include data about the current user in the correspondence — for example, a text variable in the header containing the initials of the user who is creating the letter. You can find these initials in infotype 0002 (Figure 1). First you need to create the connection between the current user (always provided in the system field SY-UNAME) and the personnel number. You can find this in subtype 0001 of infotype 0105 (Figure 2).

Figure 1

Finding the initials in infotype 0002

Figure 2

Make the connection between the current user and the personnel number

The logic looks like this:

• Start with username of the current user: field SY-UNAME
• Get the personnel number that belongs to this user from infotype 0105: field USRID in table PA0105
• Get initials from infotype 0002: field INITS in table PA0002

To implement this logic, follow these steps:

1. Create a structure (using transaction SE11) that contains the custom fields you want to fill. You can start with just one field and add other fields later.
   • Enter the name for your structure (e.g., ZAPPCOR) into the field Data Type.
   • Choose create and then structure. You’ll get the screen shown in Figure 3.
   • Enter a description.
   • Enter the names of your fields (e.g., ZINITUSER).
   • Enter a Component type (data element) or choose the built-in type for each field. Make sure that you only use the data types CHAR and NUMC and that your field is long enough for the data you want it to fill it with. Also make sure that the short description is unambiguous, because you use it later to identify the text variable.
   • Activate your structure by clicking on the Activate button or by pressing Ctrl+F3.
2. The ABAP coding to fill your text variables must be included in the program ZPAP3CUS. This doesn’t exist in the standard system, but SAP delivers a template MPAP3CUS. The fastest way is to create ZPAP3CUS by copying it from MPAP3CUS. To do this, use transaction SE38.
3. Replace T500P in ZPAP3CUS by your own structure with the custom fields (in my example ZAPPCOR). You have to do this replacement in the declaration part and in the form FILL_CUSTOMER_STRUCTURE.
4. Declare the tables you need to fill your custom fields via tables (in my example PA0002 and PA0105).
5. Fill all your custom fields in the form FILL_CUSTOMER_DATA. The basic structure of ZPAP3CUS will look like what you see in Figure 4.
6. The logic to fill the field ZAPPCOR-ZINITUSER is included in the form GET_INITIALS. As you will — over time — have a lot of custom fields to fill here, I recommend creating one form for every field in order to have a better structure in the program. In my example, the coding to fill the custom field looks like what you see in Figure 5.
7. Now, you can create as many new text variables as you want to. You only have to include them into your structure ZAPPCOR and implement the field-specific logic within the form FILL_CUSTOMER_DATA. Don’t forget to activate the program at the end.

Figure 3

Screen that appears after you select create and structure

PROGRAM zpap3cus.
TABLES: zappcor, pa0002, pa0105.
*-----------------------------------
*       FORM fill_customer_structure
*-----------------------------------
*       This routine declares the customer structures which
*       will be used in WinWord letters.
*       Necessary only if customer uses WinWord
*-----------------------------------
FORM fill_customer_structure.
  PERFORM add_customer_structure(rpaprt05) USING 'ZAPPCOR'.
ENDFORM.                    "FILL_CUSTOMER_STRUCTURE
*-----------------------------------
*       FORM fill_customer_data
*-----------------------------------
*       This routine fills the customer data for use in applicant
*      letters.
*-----------------------------------
FORM fill_customer_data.
  PERFORM get_initials USING sy-uname.
ENDFORM.                    "FILL_CUSTOMER_DATA

*&-----------------------------------*
*&      Form  get_initials
*&-----------------------------------*
*       fills the initials of the current user using infotype 0002
*-----------------------------------*
*      ->P_SY_UNAME: Username of the current user
*-----------------------------------*
FORM get_initials  USING    p_sy_uname.
  CLEAR zappcor-zinituser.
* get infotype 105 using username
SELECT SINGLE * FROM pa0105 WHERE usrid = p_sy_uname
                                AND subty = '0001'
                                AND begda LE sy-datum
                                AND endda GE sy-datum
                                AND sprps = ' '.
  IF sy-subrc = 0.  "username found
* get infotype 2 using personnel number from infotype 105
    SELECT SINGLE * FROM pa0002 WHERE pernr = pa0105-pernr
                                 AND begda LE sy-datum
                                 AND endda GE sy-datum
                                 AND sprps = ' '.
    IF sy-subrc = 0. "Person found
      zappcor-zinituser = pa0002-inits.
    endif.
  endif.
  ENDFORM.                    " get_initials

Checking the Results

The easiest way to check your result is to create an individual letter for an applicant. (Before doing this, make sure that your user name is assigned to a personnel number via infotype 0105 and that the field initials in infotype 0002 are filled for this personnel number.) Follow these steps:

1. Start transaction PB60 (menu path Personnel Management>Recruitment>Applicant activity>Maintain).
2. Chose any applicant number and click on the Execute button or press F8.
3. Create a planned activity (press F5 or use menu path Edit>Create planned activity).
4. Chose any Activity type with an MS Word-based standard text (e.g., WW-RECEIPT as shown in Figure 6) and click on Letter (the second button from the left on the bottom of the window). A window with MS Word opens.
5. Via the button Insert Merge Field, you can select the new field ZAPPCOR_ZINITUSER. As the fields are listed in alphabetical order, you’ll find this field at the end of the list (Figure 7).
6. After inserting the field, you should see the correct content in the letter. In my example it is BrGr (Figure 8).

Figure 6

Select an Activity type

Figure 7

Select the new field ZAPPCOR_ZINITUSER

Figure 8

Initials included in letter

Print or Email?

Now that the content of your correspondence is ready with the new custom fields, you can determine which way you want to send letters — printed or via email or fax. Note that within SAP standard functionality only SAPscript forms can be sent via email. MS Word documents cannot be emailed within applicant management.

If you decide to correspond via MS Word (see feature WPROC), the system expects only MS Word documents as applicant letters, so email is no longer an option as long as you stick to standard functionality. The reason is that the feature WPROC does not allow you to decide when to use SAPscript and when to use MS Word. You must decide once and for all. You can deal with this restriction with this process:

• Maintain the letters in MS Word as well as in SAPscript.
• Enter the SAPscript forms instead of the MS Word forms when you want the letter sent via email. You do this when you are maintaining applicant actions or individual applicant activities. Few users know that they can choose a letter in SAPscript in spite of the warning you receive.
• Ignore the warning messages of the system, which complain that you are using the wrong type of forms.
• Send the emails individually by using the email button in the activity window or use report RPAPRT01. (You will not find this report in the menu as long as MS Word is selected as the communication system in the feature WPROC.)

This is quite an easy workaround, but you have to work with two different programs for mass processing correspondence and you must always take care tat the correct type of form (SAPscript or MS Word) is maintained in the activities. If you have a large number of letters to send via MS Word as well as via email, you may decide either to focus on SAPscript or to develop a more sophisticated custom solution. In any case, you can always use the technique shown in this article to include your specific text variables.

Sven Ringling

Sven Ringling is executive director at iProCon (www.iprocon.de) and iProCon Human Capital Management (www.iproconhcm.co.uk). He started working as an SAP HCM consultant in 1996 and also works in strategic HR and change management. He is one of the authors of the books Mastering HR Management with SAP and HR Personnel Planning and Development Using SAP.

You may contact the author at s.ringling@iproconhcm.co.uk.

If you have comments about this article or publication, or would like to submit an article idea, please contact the editor.